{******************************************************************************}
{* Иллюстрация к книге "DirectX. Графика в проектах Delphi".                  *}
{* Издательство BHV. www.bhv.ru                                               *}
{* Краснов М.В. softgl@chat.ru                                                *}
{******************************************************************************}
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  AppEvnts,
  DirectXGraphics, DXGUtils;

type
  TfrmD3D = class(TForm)
    ApplicationEvents1: TApplicationEvents;
    procedure FormCreate(Sender: TObject);
    procedure ApplicationEvents1Minimize(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);
    procedure FormKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure ApplicationEvents1Restore(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
    FD3D            : IDIRECT3D8;
    FD3DDevice      : IDIRECT3DDEVICE8;
    FD3DVB          : IDIRECT3DVERTEXBUFFER8;
    FActive         : BOOL;
    MaterialRed     : TD3DMaterial8;
    MaterialBlue    : TD3DMaterial8;
    MaterialGreen   : TD3DMaterial8;
    MaterialYellow  : TD3DMaterial8;        
    ThisTickCount   : DWORD;
    LastTickCount   : DWORD;
    function Render : HRESULT;
    function InitD3D : HRESULT;
    function InitVB : HRESULT;
    procedure DrawScene;
    procedure Cleanup;
    procedure SetupLights;
    procedure ErrorOut (const Caption : PChar; const hError : HRESULT);
  public
    { Public declarations }
    FromX, FromY, FromZ : Single;
    AtX, AtY, AtZ : Single;
    WorldUpX, WorldUpY, WorldUpZ : Single;
    fFOV, fAspect, fNearPlane, fFarPlane : Single;    
  end;

type
  TCUSTOMVERTEX = packed record
    X, Y, Z : Single;
    nX, nY, nZ : Single;
  end;

const
  D3DFVF_CUSTOMVERTEX = D3DFVF_XYZ or D3DFVF_NORMAL;

var
  frmD3D: TfrmD3D;
  Frames : Integer = 0;

  Angle : Single = 0.0;

implementation

uses Unit2;

{$R *.DFM}

procedure TfrmD3D.Cleanup;
begin
  if Assigned (FD3DVB) then begin
     FD3DVB._Release;
     FD3DVB := nil;
  end;

  if Assigned (FD3DDevice) then begin
     FD3DDevice._Release;
     FD3DDevice := nil;
  end;

  if Assigned (FD3D) then begin
     FD3D._Release;
     FD3D := nil;
  end;
end;

procedure TfrmD3D.ErrorOut (const Caption : PChar; const hError : HRESULT);
begin
  FActive := False;
  Cleanup;
  MessageBox (Handle, PChar(DXGErrorString (hError)), Caption, 0);
end;

function TfrmD3D.InitD3D : HRESULT;
var
  d3ddm : TD3DDISPLAYMODE;
  d3dpp : TD3DPRESENT_PARAMETERS;
  hRet : HRESULT;
begin
  FD3DDevice := nil;
  FD3DVB := nil;
  FD3D := nil;

  FD3D := Direct3DCreate8(D3D_SDK_VERSION);
  if FD3D = nil then begin
     Result := E_FAIL;
     Exit;
  end;

  hRet := FD3D.GetAdapterDisplayMode(D3DADAPTER_DEFAULT, d3ddm);
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  ZeroMemory(@d3dpp, SizeOf(d3dpp));
  with d3dpp do begin
       Windowed := True;
       SwapEffect := D3DSWAPEFFECT_DISCARD;
       BackBufferFormat := d3ddm.Format;
       EnableAutoDepthStencil := True;
       AutoDepthStencilFormat := D3DFMT_D16;
  end;

  Result := FD3D.CreateDevice(D3DADAPTER_DEFAULT, D3DDEVTYPE_HAL, Handle,
                              D3DCREATE_SOFTWARE_VERTEXPROCESSING,
                              d3dpp, FD3DDevice);
end;

function TfrmD3D.Render : HRESULT;
var
  hRet : HRESULT;
begin
  if FD3DDevice = nil then begin
     Result := E_FAIL;
     Exit;
  end;

  hRet := FD3DDevice.Clear(0, nil, D3DCLEAR_TARGET or D3DCLEAR_ZBUFFER,
                           $00FFFFFF, 1.0, 0);
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3DDevice.BeginScene;
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  with FD3DDevice do begin
       SetRenderState(D3DRS_ZENABLE, D3DZB_TRUE);
       SetRenderState(D3DRS_NORMALIZENORMALS, DWORD (True));
  end;

  DrawScene;

  hRet := FD3DDevice.EndScene;
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  Result := FD3DDevice.Present(nil, nil, 0, nil);
end;

procedure TfrmD3D.FormCreate(Sender: TObject);
var
  hRet : HRESULT;
begin
  hRet := InitD3D;
  if Failed (hRet) then ErrorOut ('InitD3D', hRet);
  hRet := InitVB;
  if Failed (hRet) then ErrorOut ('InitVertex', hRet);

  SetupLights;
  MaterialRed := InitMaterial(1, 0, 0, 1);
  MaterialBlue := InitMaterial(0, 0, 1, 1);
  MaterialGreen := InitMaterial(0, 1, 0, 1);
  MaterialYellow  := InitMaterial(1, 1, 0, 1);

  FromX := 0.0;
  FromY := 0.0;
  FromZ := -6.0;

  AtX := 0.0;
  AtY := 0.0;
  AtZ := 0.0;

  WorldUpX := 0.0;
  WorldUpY := 1.0;
  WorldUpZ := 0.0;

  fFOV := 1.0;
  fAspect := 1.0;
  fNearPlane := 1.0;
  fFarPlane := 20;
end;

procedure TfrmD3D.ApplicationEvents1Minimize(Sender: TObject);
begin
  FActive := False;
end;

procedure TfrmD3D.FormActivate(Sender: TObject);
begin
  LastTickCount := GetTickCount;
  FActive := True;
end;

procedure TfrmD3D.ApplicationEvents1Idle(Sender: TObject;
  var Done: Boolean);
var
  hRet : HRESULT;
begin
  if FActive then begin
     Inc (Frames);
     hRet := Render;
     if FAILED(hRet) then begin
        FActive := False;
        ErrorOut ('Render', hRet);
        Exit;
     end;

     ThisTickCount := GetTickCount;
     if ThisTickCount - LastTickCount > 15 then begin
        Caption := 'FPS = ' + Format('%6.2f',
                                 [frames * 1000 / (ThisTickCount - LastTickCount)]);
        Frames := 0;

        Angle := Angle + 0.05;
        if Angle > 2 * Pi then Angle := Angle - 2 * Pi;

        LastTickCount := GetTickCount;
     end;
  end;

  Done := False;
end;

procedure TfrmD3D.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key = VK_ESCAPE then Close else
  if Key = VK_SPACE then with Form2 do begin
     edtFromX.Text := FloatToStr (FromX);
     edtFromY.Text := FloatToStr (FromY);
     edtFromZ.Text := FloatToStr (FromZ);

     edtAtX.Text := FloatToStr (AtX);
     edtAtY.Text := FloatToStr (AtY);
     edtAtZ.Text := FloatToStr (AtZ);

     edtWorldUpX.Text := FloatToStr (WorldUpX);
     edtWorldUpY.Text := FloatToStr (WorldUpY);
     edtWorldUpZ.Text := FloatToStr (WorldUpZ);

     edtFOV.Text := FloatToStr (fFOV);
     edtAspect.Text := FloatToStr (fAspect);
     edtNearPlane.Text := FloatToStr (fNearPlane);
     edtFarPlane.Text := FloatToStr (fFarPlane);

     Show;
  end;
end;

procedure TfrmD3D.ApplicationEvents1Restore(Sender: TObject);
begin
  FActive := True;
end;

procedure TfrmD3D.FormDestroy(Sender: TObject);
begin
  Cleanup
end;

function TfrmD3D.InitVB : HRESULT;
const
  radius = 0.1;
var
  Vertices : ^TCustomVertex;
  hRet : HRESULT;
  theta : Single;
  i : Integer;
  t : TextFile;
  wX, wY, wZ : Single;
begin
  hRet := FD3DDevice.CreateVertexBuffer((100 + 51 * 2 + 6322 * 3) * SizeOf(TCustomVertex), 0,
                                        D3DFVF_CUSTOMVERTEX,
                                        D3DPOOL_DEFAULT, FD3DVB);
  if Failed(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3DDevice.SetStreamSource(0, FD3DVB, SizeOf(TCustomVertex));
  if Failed(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3DDevice.SetVertexShader(D3DFVF_CUSTOMVERTEX);
  if Failed(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3DVB.Lock(0, (100 + 51 * 2 + 6322 * 3)* SizeOf(TCustomVertex), PByte(Vertices), 0);
  if Failed(hRet) then begin
     Result := hRet;
     Exit;
  end;

  for i := 49 downto 0 do begin
    theta := 2 * Pi * i / 49;
    Vertices.X := sin(theta) * radius;
    Vertices.Y := -1;
    Vertices.Z := cos(theta) * radius;
    Vertices.nX := sin(theta);
    Vertices.nY := 0;
    Vertices.nZ := cos(theta);
    Inc(Vertices);
    Vertices.X := sin(theta) * radius;
    Vertices.Y := 1;
    Vertices.Z := cos(theta) * radius;
    Vertices.nX := sin(theta);
    Vertices.nY := 0;
    Vertices.nZ := cos(theta);
    Inc(Vertices);
  end;

  Vertices.X := 0.0;
  Vertices.Y := 0.0;
  Vertices.Z := 1.0;
  Vertices.nX := 0.0;
  Vertices.nY := 0.0;
  Vertices.nZ := 1.0;
  Inc(Vertices);

  for i := 0 to 49 do begin
    theta := 2 * Pi * i / 49;
    Vertices.X := cos(theta);
    Vertices.Y := sin(theta);
    Vertices.Z := 0.0;
    Vertices.nX := cos(theta);
    Vertices.nY := sin(theta);
    Vertices.nZ := 1.0;
    Inc(Vertices);
  end;

  Vertices.X := 0.0;
  Vertices.Y := 0.0;
  Vertices.Z := 0.0;
  Vertices.nX := 0.0;
  Vertices.nY := 0.0;
  Vertices.nZ := -1.0;
  Inc(Vertices);

  for i := 0 to 49 do begin
    theta := 2 * Pi * i / 49;
    Vertices.X := sin(theta);
    Vertices.Y := cos(theta);
    Vertices.Z := 0.0;
    Vertices.nX := 0.0;
    Vertices.nY := 0.0;
    Vertices.nZ := -1.0;
    Inc(Vertices);
  end;

  AssignFile (t, 'teapot.txt');
  Reset (t);
  while not EOF(t) do begin
    Readln (t, wX);
    Readln (t, wY);
    Readln (t, wZ);

    Readln (t, Vertices.X);
    Readln (t, Vertices.Y);
    Readln (t, Vertices.Z);
    Vertices.nX := wX;
    Vertices.nY := wY;
    Vertices.nZ := wZ;
    Inc (Vertices);

    Readln (t, Vertices.X);
    Readln (t, Vertices.Y);
    Readln (t, Vertices.Z);
    Vertices.nX := wX;
    Vertices.nY := wY;
    Vertices.nZ := wZ;
    Inc (Vertices);

    Readln (t, Vertices.X);
    Readln (t, Vertices.Y);
    Readln (t, Vertices.Z);
    Vertices.nX := wX;
    Vertices.nY := wY;
    Vertices.nZ := wZ;
    Inc (Vertices);
  end;
  CloseFile (t);

  Result := FD3DVB.Unlock;
end;

procedure TfrmD3D.DrawScene;
var
  matView, matProj : TD3DMatrix;
  matRotate, matTranslate : TD3DMatrix;
  matRotateX, matRotateY : TD3DMatrix;
  matScale : TD3DMatrix;
begin
  SetRotateZMatrix(matRotate, Pi / 2);
  SetTranslateMatrix(matTranslate, 1.0, 0.0, 0.0);
  with FD3DDevice do begin
       SetRenderState(D3DRS_CULLMODE, D3DCULL_CCW);
       SetTransform(D3DTS_WORLD, MatrixMul(matTranslate, matRotate));
       SetMaterial(MaterialRed);
       DrawPrimitive(D3DPT_TRIANGLESTRIP, 0, 50 * 2 - 2 );
  end;

  SetRotateYMatrix(matRotate, Pi / 2);
  SetTranslateMatrix(matTranslate, 2.0, 0.0, 0.0);
  SetScaleMatrix(matScale, 1.0, 0.5, 0.5);
  with FD3DDevice do begin
       SetTransform(D3DTS_WORLD, MatrixMul(matScale,
                          MatrixMul(matTranslate, matRotate)));
       DrawPrimitive(D3DPT_TRIANGLEFAN, 100, 49);
       DrawPrimitive(D3DPT_TRIANGLEFAN, 151, 50);
  end;

  SetTranslateMatrix(matTranslate, 0.0, 1.0, 0.0);
  with FD3DDevice do begin
       SetTransform(D3DTS_WORLD, matTranslate);
       SetMaterial(MaterialGreen);
       DrawPrimitive(D3DPT_TRIANGLESTRIP, 0, 50 * 2 - 2);
  end;

  SetRotateXMatrix(matRotate, -Pi / 2);
  SetTranslateMatrix(matTranslate, 0.0, 2.0, 0.0);
  SetScaleMatrix(matScale, 0.5, 1.0, 0.5);
  with FD3DDevice do begin
       SetTransform(D3DTS_WORLD, MatrixMul(matScale,
                    MatrixMul(matTranslate, matRotate)));
       DrawPrimitive(D3DPT_TRIANGLEFAN, 100, 49);
       DrawPrimitive(D3DPT_TRIANGLEFAN, 151, 50);
  end;

  SetRotateXMatrix(matRotate, Pi / 2);
  SetTranslateMatrix(matTranslate, 0.0, 0.0, 1.0);
  with FD3DDevice do begin
       SetTransform(D3DTS_WORLD, MatrixMul(matTranslate, matRotate));
       SetMaterial(MaterialBlue);
       DrawPrimitive(D3DPT_TRIANGLESTRIP, 0, 50 * 2 - 2);
  end;

  SetTranslateMatrix(matTranslate, 0.0, 0.0, 2.0);
  SetScaleMatrix(matScale, 0.5, 0.5, 1.0);
  with FD3DDevice do begin
       SetTransform(D3DTS_WORLD, MatrixMul(matScale, matTranslate));
       DrawPrimitive(D3DPT_TRIANGLEFAN, 100, 49);
       DrawPrimitive(D3DPT_TRIANGLEFAN, 151, 50);
  end;

  SetRotateXMatrix(matRotateX, Angle);
  SetRotateYMatrix(matRotateY, Angle);
  SetTranslateMatrix(matTranslate, 0.0, -1.5, 0.0);
  SetScaleMatrix(matScale, 0.5, 0.5, 0.5);
  with FD3DDevice do begin
       SetTransform(D3DTS_WORLD, MatrixMul(matRotateX,
                    MatrixMul(matRotateY,
                    MatrixMul(matScale, matTranslate))));
       SetMaterial(MaterialYellow);
       SetRenderState(D3DRS_CULLMODE, D3DCULL_CW);
       DrawPrimitive(D3DPT_TRIANGLELIST, 100 + 51 * 2, 6322);
  end;

  SetViewMatrix(matView, D3DVector(FromX, FromY, FromZ),
                         D3DVector(AtX, AtY, AtZ),
                         D3DVector(WorldUpX, WorldUpY, WorldUpZ));
  FD3DDevice.SetTransform(D3DTS_VIEW, matView);

  SetProjectionMatrix(matProj, fFOV, fAspect, fNearPlane, fFarPlane);
  FD3DDevice.SetTransform(D3DTS_PROJECTION, matProj);
end;

procedure TfrmD3D.SetupLights;
var
  Light0     : TD3DLight8;
  Light1     : TD3DLight8;
begin
  Light0 := InitDirectionalLight(D3DVector(-1, -1, -1), 1, 1, 1, 0);

  FD3DDevice.SetLight(0, Light0);

  Light1 := InitDirectionalLight(D3DVector(0, 0, 1), 1, 1, 1, 0);
  FD3DDevice.SetLight(1, Light1);

  FD3DDevice.LightEnable(0, True);
  FD3DDevice.LightEnable(1, True);
end;

end.
