{******************************************************************************}
{* Иллюстрация к книге "DirectX. Графика в проектах Delphi".                  *}
{* Издательство BHV. www.bhv.ru                                               *}
{* Краснов М.В. softgl@chat.ru                                                *}
{******************************************************************************}
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  AppEvnts,
  DirectXGraphics, DXGUtils;

type
  TfrmD3D = class(TForm)
    ApplicationEvents1: TApplicationEvents;
    procedure FormCreate(Sender: TObject);
    procedure ApplicationEvents1Minimize(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);
    procedure FormKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure ApplicationEvents1Restore(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
    FD3D            : IDIRECT3D8;
    FD3DDevice      : IDIRECT3DDEVICE8;
    FD3DVB          : IDIRECT3DVERTEXBUFFER8;
    FActive         : BOOL;
    FD3Texture1     : IDIRECT3DTEXTURE8;
    ThisTickCount   : DWORD;
    LastTickCount   : DWORD;
    function Render : HRESULT;
    function InitD3D : HRESULT;
    function InitVB : HRESULT;
    function InitTexture (var FD3Texture : IDIRECT3DTEXTURE8;
                          const FileName : String) : HRESULT;
    procedure SetupMatrices;
    procedure SetupLights;
    procedure Cleanup;
    procedure ErrorOut (const Caption : PChar; const hError : HRESULT);
    procedure InitData;
  public
    { Public declarations }
  end;

type
  TCUSTOMVERTEX = packed record
    X, Y, Z : Single;
    nX, nY, nZ : Single;
    Color : DWORD;
    U, V : Single;
  end;

const
  D3DFVF_CUSTOMVERTEX = D3DFVF_XYZ or D3DFVF_NORMAL or D3DFVF_DIFFUSE or D3DFVF_TEX1;

var
  frmD3D: TfrmD3D;
  Frames : Integer = 0;

{$I player.pas}

implementation

{$R *.DFM}

procedure TfrmD3D.Cleanup;
begin
  if Assigned (FD3Texture1) then begin
     FD3Texture1._Release;
     FD3Texture1 := nil;
  end;

  if Assigned (FD3DVB) then begin
     FD3DVB._Release;
     FD3DVB := nil;
  end;

  if Assigned (FD3DDevice) then begin
     FD3DDevice._Release;
     FD3DDevice := nil;
  end;

  if Assigned (FD3D) then begin
     FD3D._Release;
     FD3D := nil;
  end;
end;

procedure TfrmD3D.ErrorOut (const Caption : PChar; const hError : HRESULT);
begin
  FActive := False;
  Cleanup;
  MessageBox (Handle, PChar(DXGErrorString (hError)), Caption, 0);
end;

function TfrmD3D.InitD3D : HRESULT;
var
  d3ddm : TD3DDISPLAYMODE;
  d3dpp : TD3DPRESENT_PARAMETERS;
  hRet : HRESULT;
begin
  FD3Texture1 := nil;
  FD3DDevice := nil;
  FD3DVB := nil;
  FD3D := nil;

  FD3D := Direct3DCreate8(D3D_SDK_VERSION);
  if FD3D = nil then begin
     Result := E_FAIL;
     Exit;
  end;

  hRet := FD3D.GetAdapterDisplayMode(D3DADAPTER_DEFAULT, d3ddm);
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  ZeroMemory(@d3dpp, SizeOf(d3dpp));
  with d3dpp do begin
       Windowed := True;
       SwapEffect := D3DSWAPEFFECT_DISCARD;
       BackBufferFormat := d3ddm.Format;
       EnableAutoDepthStencil := True;
       AutoDepthStencilFormat := D3DFMT_D16;
  end;

  Result := FD3D.CreateDevice(D3DADAPTER_DEFAULT, D3DDEVTYPE_HAL, Handle,
                              D3DCREATE_SOFTWARE_VERTEXPROCESSING,
                              d3dpp, FD3DDevice);
end;

function TfrmD3D.Render : HRESULT;
var
  hRet : HRESULT;
begin
  if FD3DDevice = nil then begin
     Result := E_FAIL;
     Exit;
  end;

  hRet := FD3DDevice.Clear(0, nil, D3DCLEAR_TARGET or D3DCLEAR_ZBUFFER, $00FFFFFF,
  1.0, 0);
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3DDevice.BeginScene;
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  with FD3DDevice do begin
       SetRenderState(D3DRS_CULLMODE, D3DCULL_CCW);
       SetTexture(0, FD3Texture1);

       SetTextureStageState(0, D3DTSS_COLOROP, D3DTOP_MODULATE);
       SetRenderState(D3DRS_LIGHTING, DWORD (True));
  end;

  SetupMatrices;

  hRet := FD3DDevice.EndScene;
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  Result := FD3DDevice.Present(nil, nil, 0, nil);
end;

procedure TfrmD3D.FormCreate(Sender: TObject);
var
  hRet : HRESULT;
  View, Proj : TD3DMatrix;
begin
  hRet := InitD3D;
  if Failed (hRet) then ErrorOut ('InitD3D', hRet);
  hRet := InitVB;
  if Failed (hRet) then ErrorOut ('InitVertex', hRet);
  hRet := InitTexture (FD3Texture1, 'Player_0.bmp');
  if Failed (hRet) then ErrorOut ('InitTexture', hRet);

  InitData;

  SetupLights;

  SetViewMatrix(View, D3DVector(0.8, 0.8, 0), D3DVector(0, 0, 0), D3DVector(0, 0, 1));
  FD3DDevice.SetTransform(D3DTS_VIEW, View);

  SetProjectionMatrix(Proj, 1, 1, 0.1, 5);
  FD3DDevice.SetTransform(D3DTS_PROJECTION, Proj);
end;

procedure TfrmD3D.ApplicationEvents1Minimize(Sender: TObject);
begin
  FActive := False;
end;

procedure TfrmD3D.FormActivate(Sender: TObject);
begin
  LastTickCount := GetTickCount;
  FActive := True;
end;

procedure TfrmD3D.ApplicationEvents1Idle(Sender: TObject;
  var Done: Boolean);
var
  hRet : HRESULT;
begin
  if FActive then begin
     Inc (Frames);
     hRet := Render;
     if FAILED(hRet) then begin
        FActive := False;
        ErrorOut ('Render', hRet);
        Exit;
     end;

     ThisTickCount := GetTickCount;
     if ThisTickCount - LastTickCount > 15 then begin
        Caption := 'FPS = ' + Format('%6.2f',
                                 [frames * 1000 / (ThisTickCount - LastTickCount)]);
        Frames := 0;

        LastTickCount := GetTickCount;
     end;
  end;

  Done := False;
end;

procedure TfrmD3D.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key = VK_ESCAPE then Close;
end;

procedure TfrmD3D.ApplicationEvents1Restore(Sender: TObject);
begin
  FActive := True;
end;

procedure TfrmD3D.FormDestroy(Sender: TObject);
begin
  Cleanup
end;

function TfrmD3D.InitVB : HRESULT;
var
  hRet : HRESULT;
begin
  hRet := FD3DDevice.CreateVertexBuffer(408 * 3 * SizeOf(TCustomVertex), 0,
                                        D3DFVF_CUSTOMVERTEX,
                                        D3DPOOL_DEFAULT, FD3DVB);
  if Failed(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3DDevice.SetStreamSource(0, FD3DVB, SizeOf(TCustomVertex));
  if Failed(hRet) then begin
     Result := hRet;
     Exit;
  end;

  Result := FD3DDevice.SetVertexShader(D3DFVF_CUSTOMVERTEX);
end;

procedure TfrmD3D.SetupMatrices;
begin
  FD3DDevice.DrawPrimitive(D3DPT_TRIANGLELIST, 0, 408);
end;

procedure TfrmD3D.SetupLights;
var
  Light0 : TD3DLight8;
  Light1 : TD3DLight8;
begin
  Light0 := InitDirectionalLight(D3DVector(-1, -1, 0), 1, 1, 1, 0);
  Light1 := InitDirectionalLight(D3DVector(0, -1, 0), 1, 1, 1, 0);

  FD3DDevice.SetLight(0, Light0);
  FD3DDevice.LightEnable(0, True);
  FD3DDevice.SetLight(1, Light1);
  FD3DDevice.LightEnable(1, True);
end;

procedure TfrmD3D.InitData;
var
  i, j : Integer;
  Vertices : ^TCustomVertex;
  vi : Integer;
  ni : Integer;
  ti : Integer;
begin
  FD3DVB.Lock(0, 408 * 3 * SizeOf(TCustomVertex), PByte(Vertices), 0);

  for i := 0 to 407 do
      for j := 0 to 2 do begin
      vi := face_indicies[i][j];
      ni := face_indicies[i][j+3];
      ti := face_indicies[i][j+6];

         Vertices.X := Avertices[vi][0];
         Vertices.Y := Avertices[vi][1];
         Vertices.Z := Avertices[vi][2];

         Vertices.nX := normals[ni][0];
         Vertices.nY := normals[ni][1];
         Vertices.nZ := normals[ni][2];

         Vertices.Color := $00FFFFFF;

         Vertices.U := textures[ti][0];
         Vertices.V := textures[ti][1];

         Inc(Vertices);
  end;

  FD3DVB.Unlock;
end;

function TfrmD3D.InitTexture (var FD3Texture : IDIRECT3DTEXTURE8;
                              const FileName : String) : HRESULT;
var
  hRet : HRESULT;
  d3dlr : TD3DLOCKED_RECT;
  dwDstPitch : DWORD;
  X, Y : DWORD;
  Bmp : tBitmap;
  R, G, B : Byte;
begin
  Bmp := TBitmap.Create;
  Bmp.LoadFromfile (FileName);

  hRet := FD3DDevice.CreateTexture (Bmp.Width, Bmp.Height, 0, 0,
                                    D3DFMT_A8R8G8B8,
                                    D3DPOOL_MANAGED, FD3Texture);
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  hRet := FD3Texture.LockRect(0, d3dlr, nil, 0);
  if FAILED(hRet) then begin
     Result := hRet;
     Exit;
  end;

  dwDstPitch := d3dlr.Pitch;
  for Y := 0 to Bmp.Height - 1 do
      for X := 0 to Bmp.Width - 1 do begin
         R := GetRValue (Bmp.Canvas.Pixels [X, DWORD (Bmp.Height - 1) - Y]);
         G := GetGValue (Bmp.Canvas.Pixels [X, DWORD (Bmp.Height - 1) - Y]);
         B := GetBValue (Bmp.Canvas.Pixels [X, DWORD (Bmp.Height - 1) - Y]);

         PDWORD (DWORD(d3dlr.pBits) + Y * dwDstPitch + X * 4)^ := D3DCOLOR_ARGB(127, R, G, B)
  end;
  Bmp.Free;

  Result := FD3Texture.UnlockRect(0);
end;

end.
